Script Looter Not looting brigands

[Banshee]

This is my Friend Niks looter. He has since quite playing and I have not been able to contact him. I was hopping some one could show me what I am missing. I have read threw every section trying to find out why this thing will not loot brigands, murderers, or other humanoid type mobs.

 

Code: [Select]

;===================
; Script Name: NiksLooter
; Author: Nik
; Version: 3.4.1
; Client Tested with: Latest
; EUO version tested with: 1.5 Build 183
; Shard OSI / FS: FS Paradise Found
; Public Release: 13 Mar 2011
; Purpose: This loots corpses with either Grab All or Loot
; NOTE: To use LOOT you must set a loot to bag!
;       If using Claim it will claim regardless of whats left on the corpse.
;       make sure you add item types for things you want to loot to the list below.
;===================


;##############################  YOU MUST SET ME!!!!! ##############################
set %GrabBag #BACKPACKID


;##################  You can change / add to me if you want ########################
set %loot RQF_XZY_KDF_EU_POF_ZSL_SVH_ATS_HTD_HEJ_ETH_DTH_QUF_VMK_DWR_EWR_WY_FWR_DWR_GWR_DUN_UDF_DYM_QFAB_HAG_ITK_HZG_TKG_GLG    ;list of items to manualy loot.
set %knife GFR_HNF_XFR_NMH                                                      ;ItemTYPE of knife to skin with.


; UDF Fishing Net
; KDF Magical Fishing Pole

;###################################################################################
;###################################################################################
;###################################################################################
;############################                           ############################
;############################   DONT TOUCH BELOW HERE   ############################
;############################                           ############################
;###################################################################################
;###################################################################################
;###################################################################################

set #LPC 500

 menu clear
 Menu window size 205 150
 Menu show
 Menu window color $F2F2F2
 Menu Window Title NikLooter
 Menu font bgcolor $F2F2F2
 menu font color red
 menu font size 10
 menu text text3 95 29 OR
 Menu Text text1 3 3 Select One
 menu font color blue
 menu text text2 3 60 Options
 Menu font color Black
 Menu font size 18
 menu shape blah 5 20 195 35 4 7 2 red 2 black
 menu shape blah1 5 77 195 35 4 7 2 blue 2 black
 menu check grab 15 25 80 25 #FALSE Grab
 menu check loot 120 25 70 25 #FALSE Loot
 menu check skin 120 82 70 25 #FALSE Skin
 menu check Claim 15 82 90 25 #FALSE Claim
 menu check Reset 15 118 200 25 #FALSE Reset Ignores



main:

menu get grab
if #menures = -1
gosub grab

menu get loot
if #menures = -1
gosub loot

menu get Reset
if #MENURES = -1
gosub reset
wait 1
goto main:




;##################  Grab  ########################
sub Grab


finditem YFM G_2
event property #FINDID
if remains in #PROPERTY
{
ignoreitem #FINDID
return
}
if #FINDCNT > 0
{
set %jstart #JINDEX
set %grabmob #FINDID
ignoreitem #FINDID
menu get skin
     if #menures = -1
     gosub skin
grab:
set #LTARGETID %grabmob
set #LTARGETKIND 1
set #TARGCURS 0
event macro 1 0 [ga
target
event macro 22
wait 10
set %jend #jindex
for %ji %jstart %jend

{
scanjournal %ji
if You_grabbed_the_loot in #journal
  {
  ignoreitem %grabmob
  deletejournal
  }
}


menu get claim
     if #menures = -1
     gosub claim
}
return

;##################  loot  ########################
sub loot

finditem YFM G_2
event property #FINDID
if remains in #PROPERTY
{
ignoreitem #FINDID
return
}
if #FINDCNT > 0
{
set %lootmob #FINDID
set #LOBJECTID %lootmob
set #NEXTCPOSX 552
set #NEXTCPOSY 784
event macro 17 0
wait 10
loot:
gosub CheckBookCheck
gosub CorpseCheck
finditem POF_CPF_IGR_YFM C_ , %lootmob
if #FINDCNT > 0
{
exevent drag #FINDID #FINDSTACK
wait 7
exevent dropc %golddrop
wait 7
goto loot:
}
gosub CorpseCheck
finditem %loot C_ , %lootmob
if #FINDCNT > 0
{
exevent drag #FINDID #FINDSTACK
wait 7
exevent dropc %GrabBag
wait 7
goto loot:
}
menu get skin
     if #menures = -1
     gosub skin
grab:
finditem %lootmob G_2 IGR_YFM
if #FINDCNT > 0
{
set %jstart #JINDEX
event sysmessage .
set #LTARGETID %lootmob
set #LTARGETKIND 1
set #TARGCURS 0
event macro 1 0 [ga
target 2s
event macro 22
wait 10
set %jend #JINDEX
for %ji %jstart %jend
{
    scanJournal %ji
    if You_grabbed_the_loot! in #journal
        goto moveon
}
goto grab:
moveon:
ignoreitem %lootmob
menu get claim
     if #menures = -1
     gosub claim

}
}
return


sub CorpseCheck
if #findtype in CTD_DLN_CUD_UXM_CKF_JKF_TXM_ZTD_VMF_TMF_LKF_AUD_OKF_ZJF_YFM
if #CONTID = %lootmob
return
finditem * C_IGR , %lootmob
if #FINDCNT = 0
gosub loot
}
return
;##################  skin  ########################
sub skin
chooseskill forensic
if #SKILL >= 1000
{
     set #LTARGETKIND 1
     set #LTARGETID %lootmob
     event macro 13 19
     target
     event macro 22 0
     wait 10
}

finditem GFR C
if #FINDCNT > 0
{
     set #LOBJECTID #FINDID
     set #TARGCURS 0
     event macro 17
     target 2s
     set #LTARGETKIND 1
     set #LTARGETID %lootmob
     event macro 22
     wait 10
     return
}

finditem %knife C
if #FINDCNT > 0
{
     set #LOBJECTID #FINDID
     set #TARGCURS 0
     event macro 17
     target 2s
     set #LTARGETKIND 1
     set #LTARGETID %lootmob
     event macro 22
     wait 10
}
else
{
display ok No Knife Found, Pausing
Pause
}
return
;##################  claim  ########################
sub claim
     claim:
     set #TARGCURS 0
     event macro 1 0 [cl
     target 2s
     set #LTARGETID %lootmob
     set %LTARGETKIND 1
     event macro 22 0
     wait 10
     finditem %lootmob G_2
     if #FINDCNT > 0
     goto claim:
return

;##################  reset  ########################
sub reset
wait 20
ignoreitem Reset
menu set reset 0
return


;##################  CheckBook Check  ########################
sub CheckBookCheck
; CHECKBOOK CHECK
check:
finditem DYM C
if #FINDCNT > 0 && #FINDCOL = 2033
{
set %golddrop #FINDID
return
}
if #FINDCNT > 1 && #FINDCOL <> 2033
{
ignoreitem #FINDID
goto check:
}
else
set %golddrop #BACKPACKID
return


[Masscre]

It appears that he was using event property to find the corpse and this is not working for huminoids i believe. I just ran though the code and did not actually try it. There are a few item types that are only used for corpses and this would be how I would have done it. Someone else may have a different idea on it.

[Banshee]

Does this mean that it cant be changed to loot brigands.

[Endless Night]

sure it can.

first things first you need to find out the item type for humaniod corpses.

When you open a humaniod corpse before doign anything else what does the #conttype get set to (in right hand collumn of easyuo under the containor info section)

[Banshee]

I went to buc's den and killed many murderers every one I opened sai YFM for #conttype. I had tried adding that into several places but with no luck. Other Looter I use will loot huminoid bodies, problem is they do not have the grab all ([GA) function or the claim ([CL) function that is needed for my shard.

[ximan]

Might try commenting out the following lines in both sub grab and sub loot:

event property #FINDID
if remains in #PROPERTY
{
ignoreitem #FINDID
return
}

[Banshee]

Wow thanks. it worked perfect . You know I had tried something like that before except I removed  finditem YFM G_2 and so It broke all together. Guess I need more studying on how this stuff works

[The Ghost]

I just try it  and at line 88 I add the  X here  :: finditem YFM_X  G_2 ::      that was for the Red mage healer.  I did loot his gold.  Now at the second mage, nothing happen. I'm still trying to find why.   I kill a deer and the skin didn't work and not sure what he the grab option.  I will read a bit more.

[Banshee]

This script is set up for a free shard that has some option I don't think that OSI has. [GA gives you a target hand that you select a corps from and it will gather all stackables. [CL is a function That as far as I know is only on my shard. It deletes the mob and rewards you with 1 platinum coin. Platinum can be used to buy some very useful items but cost large amounts of plat. as much as 25K that's a lot of monsters to claim.

[The Ghost]

ThX for the info.  I play on OSI.   Nice little looter.

[Endless Night]

glad the community could help you out banshee...  just for a little lession the "finditem"  comamnd is what finds the corpses...   Actually finditem will find anything but adding the YFM type means only look for corpses.. and the G_2 means on the ground in a radius of 2 spaces from your character.

So for example if you wanted to look for gold on the ground in a 20 tile radius you would do finditem POF G_20   (pof being the type code for gold)

[Banshee]

Neet. so that is what the G_# means. Wow I am going to finally learn so much about how this all works. I already love this forum. I hope to learn more of this kinda info.

[Endless Night]

Neet. so that is what the G_# means. Wow I am going to finally learn so much about how this all works. I already love this forum. I hope to learn more of this kinda info.

Well you can always look at the wiki,... it does a decent job of explaining commands.. if your stuck after reading  about a particular command .. just ask

http://wiki.easyuo.com/index.php/Documentation

[NObama]

I <3 the EasyUO documentation wiki.  It is absolutely vital and I have several bookmarks devoted to pages I visit frequently.

[KaliOfLS]

You make me sad banshee
https://www.easyuo.com/forum/viewtopic.php?f=3&t=49106

That looter that i put in the script for you would have worked.. even had your shard's claim support

:sulks: