Version 2.1b
Removed all goto's as a birthday gift for Cerveza!

Also removed previous versions.... This should be working fine...

I haven't tested 2.1b myself yet, so, if there are any problems, please tell me about it!

Cheers!

Thanks frneo, Cerveza & camotbik
I'm going to go over it today and spend some time on the tutorials also. I guess i was trying to run before I could walk.
Thanks for taking the time frneo for explaining how each part works it helped  alot im adding other items to the script and ill post up the finished script.

You're welcome!
I'm glad I could help!

If you have any questions on this new version of yours, feel free to ask!

Hi Blacklisted! I wrote the script down for you, to do the stuff you wanted it to do, with comments, in the form of a tutorial. This script should be fully functional, and also, it's an easy to read tutorial so that you can understand everything that each line of code does. I hope you can find this useful to help give you a push in the right direction to start learning how to script.

So, here it is:
;----------------------------------------------------
; First off, we should start the script by setting the
; variables we're going to use. As you know, standard
; variables always start with '%'. So let's set the ones
; we're going to use!
;----------------------------------------------------
set %gems HVF_UVF_FVF_EVF_OVF_VUF_GVF_RVF_BVF_VVF_NVF_ZVF_
set %reagents KUF_JUF_KZF_JZF_MZF_WZF_RZF_SZF_DUF_TZF_UZF_YZF_IUF_
;-------------------------------------------------------------
; I just copied the gems and reagents types from the code you
; posted on SUO. Saved me some time! :)
; Now, even though we're going to use the menu to define
; the bags' id's, we should start the script off by setting
; the vars we're going to use to N/A. This has two basic
; purposes:
; First one is so that the user sees the bags N/A in the menu,
; making it easier for him to realize he has to set the bags.
; You should always think on ways to make the script more
; intuitive for people who will be using it.
; Remember, not every person who is going to use your script
; is gonna be a rocket scientist! :))
; Second purpose is so that we can put a check to see if the bag
; has been set or not in the menu, before the script starts
; doing it's job of moving items.
; So let's get those N/A's going!
; (actually, if you don't specify the vars, they will be 'set'
; automatically to N/A, but I've wrote it like this
; to ilustrate better what I'm trying to show you!) :)
;-------------------------------------------------------------
set %lootbag N/A
set %gemsbag N/A
set %regsbag N/A

;--------------------------------------------------
; Next, the most basic yet very important thing you should
; know is how subs work. You always use 'gosub subname'
; to go to a sub, however, you should only get out
; of a sub using 'return'. This will take you
; back to where the sub was called in the
; first place (the gosub line).
;
; The example we're gonna see now shows this
; clearly. We're gonna generate the menu for the
; user. We'll use a sub for that!
; So first things first.
;-----------------------------------------------------
gosub menu ; This line here will take you to the sub called
; 'menu'. If you scroll down you can find this sub, and
; you'll notice the last line of it being 'return'.
; So that return will take us back exactly here, where
; we used the 'gosub' command.
;----------------------------------------------------
; Ok, so now our pretty little menu should be built, and the
; user should be seeing it right now! YAY! \0/
; Now, we have to make the script wait here until the
; user clicks something to do whatever the hell he wants
; to have the script do for him. We're going to write
; a little loop to do this. Read this loop carefully
; to see how it works.
;----------------------------------------------------

repeat
if #menubutton = setloot_button
   {
   gosub setloot
   set #menubutton N/A
   }
if #menubutton = setgems_button
   {
   gosub setgems
   set #menubutton N/A
   }
if #menubutton = setregs_button
   {
   gosub setregs
   set #menubutton N/A
   }
if #menubutton = moveregs_button
   {
   if %regsbag <> N/A && %lootbag <> N/A
      {
      gosub moveregs
      set #menubutton N/A
      }
   else
      {
      Display You must set up each bag first
      set #menubutton N/A
      }
   }
if #menubutton = movegems_button
   {
   if %gemsbag <> N/A && %lootbag <> N/A
      {
      gosub movegems
      set #menubutton N/A
      }
   else
      {
      Display You must set up each bag first
      set #menubutton N/A
      }
   }
until #false ; thank you cerveza! :)

;--------------------------------------------------
; Ok, our main loop is done. When the user clicks
; a button, we can see that in the #menubutton
; var. Things you should notice here:
; 1) If a button is pressed, you will go to a sub
;    which will perform what the button suggests.
;    Also, you will set the #menubutton var back to
;    N/A so that you don't keep looping like crazy
;    the same sub over and over.
; 2) If the person tries to use the move subs
;    without having set the ID's of the bags first,
;    the script will warn them about it, and go back
;    to the loop to wait for the bag id's to be set.
;----------------------------------------------------
; I guess now that this is done, we can start building the
; rest of our subs! Let's start with the sub to set
; our loot bag!
;------------------------------------------------------

;======= Set Loot Bag Sub =======
sub setloot
event SysMessage Target your loot bag ; event SysMessage will display a msg inside you client for you
      set #targcurs 1 ;sets the little target cursor on
      while #targcurs = 1 ; while #targcurs = 1, so while the target cursor is on, it will wait
      wait
      set %lootbag #ltargetid ; once the bag is clicked, we will set it's id
      set #lobjectid #ltargetid ; here we will set the last object to the id of the last target, in this case, our loot bag
      event macro 17 ; event macro 17 is 'Use Last Object', so this will open our loot bag
      menu Edit EUOEdit1 84 44 57 %lootbag
      wait 20
return
;======= End Sub =======

;--------------------------------------------------------
; Noticed the line 'menu Edit EUOEdit1 84 44 57 %lootbag' there?
; This will update the Edit Box for the lootbag in the menu,
; which will now show the id of our dear lootbag!
; Great stuff! Now we're gonna do almost the same thing for
; our other two bags. The difference is, we're not gonna want to open them.
; Why, do you ask? Simply because it would make this more complicated.
; So it's best to leave bags we're going to put stuff IN closed, while
; the bags we're going to get stuff FROM should remain open.
; So, let's do this now!
;---------------------------------------------------------

;======= Set Gems Bag Sub =======
sub setgems
event SysMessage Target your gems bag
      set #targcurs 1
      while #targcurs = 1
      wait
      set %gemsbag #ltargetid
      set #lobjectid #ltargetid
      menu Edit EUOEdit2 84 72 57 %gemsbag
return
;======= End Sub =======

;======= Set Regs Bag Sub =======
sub setregs
event SysMessage Target your regs bag
      set #targcurs 1
      while #targcurs = 1
      wait
      set %regsbag #ltargetid
      set #lobjectid #ltargetid
      menu Edit EUOEdit3 84 104 57 %regsbag
return
;======= End Sub =======

;--------------------------------------
; Piece of cake right? Now, we should write up
; the move subs. So lets get it done!
;----------------------------------------

;======= Move Regs Sub =======
sub moveregs
repeat ; it will repeat whatever is written here, until the condition on the 'until' line is met
finditem %reagents C_ , %lootbag ; this will look for the reagents inside you're lootbag
exevent drag #findid #findstack ; #findstack will hold the amount of reagents in each stack
wait 10
exevent dropc %regsbag ; this line will drop the regs inside your regs bag
wait 10
until #findcnt < 1 ; if you can't find any more items, it will stop repeating!
Display All Done!
return
;======= End Sub =======

;======= Move Gems Sub =======
sub movegems
repeat
finditem %gems C_ , %lootbag
exevent drag #findid #findstack
wait 10
exevent dropc %gemsbag
wait 10
until #findcnt < 1
Display All Done!
return
;======= End Sub =======

;--------------------------------------
; Ok, we should be set now! If no mistake was
; made while writing, this little script
; should do what we expect from it!
; Let's hit play and find out! :))
;--------------------------------------
; Below you can check out the menu sub.
;--------------------------------------


;======= Menu Sub =======
sub menu
menu Clear
menu Window Title Blacklisted's MoveLoot
menu Window Color BtnFace
menu Window Size 221 225
menu Font Transparent #true
menu Font Align Right
menu Font Name MS Sans Serif
menu Font Size 8
menu Font Style
menu Font Color WindowText
menu Font Transparent #false
menu Font Align Left
menu Text EUOLabel1 12 44 Loot Bag ID:
menu Text EUOLabel2 12 72 Gems Bag ID:
menu Text EUOLabel3 12 104 Regs Bag ID:
menu Text EUOLabel4 12 144 Move regs to bag:
menu Text EUOLabel5 12 172 Move gems to bag:
menu Button setloot_button 148 44 43 25 Set
menu Font BGColor Window
menu Edit EUOEdit1 84 44 57 %lootbag
menu Font BGColor BtnFace
menu Button setgems_button 148 72 43 25 Set
menu Font BGColor Window
menu Edit EUOEdit2 84 72 57 %gemsbag
menu Font BGColor BtnFace
menu Button setregs_button 148 104 43 25 Set
menu Font BGColor Window
menu Edit EUOEdit3 84 104 57 %regsbag
menu Font BGColor BtnFace
menu Button moveregs_button 124 144 43 25 Go
menu Button movegems_button 124 172 43 25 Go
menu Show 421 270
return
;======= End Sub =======

;----------------------------------------------
; Well, I hope this could point you in the right
; direction to start writing your own scripts!
; I know we can get overwhelmed sometimes, when
; we try to read huge pages of things we
; still don't understand very well. So I hope
; this has made things a little simpler for you!
; Cheers,
;
; frneo
;------------------------------------------------
; End Script
;------------------------------------------------
Just copy this to your EUO. You will find detailed explanations on (almost) everything the code is meant for, and I tried to keep it as simple as possible.

I gave you a few explanations on the use of the menu too.



If you have any questions, just ask and I'll get back to you as soon as possible.

Hope this helps!

Cheers!

No reason to thank me...you're the one making my sampire's life all that much easier.

2.1 downloaded and running now.  Only about 5 hammers in so far, but yes, it is MUCH faster.  I know what I'll be doing the rest of the night!

(For those that want to craft more than 6 items, the new line to change is 904)  if %trashcnt >=6  Sneaky of you to change the var

As for me, I'm not seeing where to change the amount of ingots it grabs. Can you point me in the right direction?  I usually keep my pack almost empty, so crafting 30-40 items at a time is pretty easy.

Thanks again for the phenomenal tool frneo!

I had to change the var to %trashcnt because the check I was using in version 2.0 wouldn't work with this new code.

Also, the amount of ingots it grabs is 7 times the amount necessary to make your weapon. So, if the weapon you're making uses 8 ingots, it will grab 56 ingots from the secure, as soon as you have less than 8 ingots in your backpack.

You can find this on line 229
set %amount %minimum * 7So, if you increase this number here, it will increase the amount of ingots to grab from the secure, according to the amount necessary to make your weapon...

Hope this helps...

Cheers

Hey there frneo,

I know myself and many others have been hoping to find something like this for quite some time now, so thank you.

I just gave it a run with 20 DC hammers, and it works flawlessly.  Fantastic job.

One thing that I noticed as I was watching it for a while. (And I'm not really sure if this is really an option, but just a suggestion if nothing more.)  I believe that you could almost double the speed of the script if you were to craft the weapons directly into your unravel bag.  Drop your ingots into that bag and crafting there would cut out the need to drag and drop every item made into that container.  Then after crafting 6, or however many, scan the bag and pull any that qualify into your keepers container.

I've always liked crafting directly into my unravel/recycle bags just so I don't have to move things around. 

Regardless, your script is fantastic and I thank you for taking the time to put it together.  I have thousands of low end hammers that I've been wanting to burn, but doing them while sitting here was awful boring.

Thank you.

You're welcome! Thank you for the kind words!

And I gotta say, I love the idea of crafting the weapons directly in the unravel bag... I'm definitely gonna look into that! Thank you for the suggestion!

Cheers!

Never had a problem with mana...it's dead quite fast and I always seem to have the mana for another AI from leeching

Thanks, that's what I wanted to know...

Cheers!

I use a wraith form thrower myself so weapon make up is life / stam / ssi / damage / dragon slayer.

120 bush / healing type template.

Can curse weapon if you ever get too low.

Honor him and come down off the stairs, turn left and just start going clockwise.

Never turn in towards him or you get frozen.

Just keep going in a circle clockwise and AI.

Takes about 5-7 minutes to kill and never die.

Who needs teleporters!!

If you don't have mana leech on your weapon, won't you stop leeching mana through wraith form once the dragon is out of mana?

You could have it smelt.

Yes, that's a good idea...

However, if it's possible to unravel with 0 skill in imbuing, I think it would be more profitable to unravel still...

Can anyone confirm this? If it's confirmed that one can't unravel with 0 skill, I would definitely add an option to smelt the weapons in the next release...


Cheers!

EDIT: Just confirmed it... With 0 skill in imbuing you're still able to unravel... You will get only Magical Residue though... However, it still outweighs the benefits of smelting....
The only downside would be if you don't have access to a Soulforge near your secures I guess...