same itemtype

[Crisis]

saltpeter, charcoal, potash, and black powder all have the same item type.

Obviously if you want the script to distinguish between the 4, you cannot use finditem. The itemid will change with each stack. How can you tell a script which to pull and which not to pull or is it impossible since OSI gave them the same itemtype?

[Pearls]

I'm just getting into it myself but you could try iterating through the items and check property & parse the string Just a guess hehe. Hopefully there's better way

[TrailMyx]

Like Pearls said, checking the item property is a good bet.  Also, if the item is a different color, you can rely on the #FINDCOL variable to distinguish between items.  This works for things like ingots and logs/boards.

[Crisis]

How would you set that and then call on it on a script so it can move them into your bag and then out of your bag?

Something like this?

set %saltpeter 1150

findcol %saltpeter C_ , #backpackid

[gimlet]

Check out this sub from TM's FAF

Spoiler: show

;-------------------------------------------------------------------------------
; %1 = item kind or id
; %2 = container id
; %3 = menu button
; %4 = #true for a stackable item
sub CheckandDragSpecial
  set %tempitemid %1
  set %tempcontid %2
  set %tempmenu %3
  set %tempstackable %4
 
  menu Get %tempmenu ; check specified menu radio button?
  if #MENURES = #true
  {
checkanddragagain:
    finditem %tempitemid C_ , %tempcontid
    if #FINDKIND <> -1
    {
      if #FINDTYPE = HTD
      {
        event property #FINDID
        if message NOTIN #property  ; this is just a bottle of ale
        {
          ignoreitem #FINDID 2
          goto checkanddragagain
        }
      }
      if #FINDTYPE = UDF ; net, but colored
      {
        if %tempmenu = EUOCheckBox19  ; just take the colored ones?
        {
          menu get EUOCheckBox19
          if ( #MENURES = #true ) && ( #FINDCOL = 2208 )
          {
            ignoreitem #FINDID 2 ; it's plain, forget it
            goto checkanddragagain
          }
        }
      }
      if #FINDTYPE = HTD ; MIB, but ancient?
      {
        if %tempmenu = EUOCheckBox21 ; check for ancient MIB
        {
          set #LOBJECTID #FINDID
          event macro 17 0
          wait 30
          event property #FINDID
          if ancient notin #PROPERTY
          {
            menu get EUOCheckBox8 ; just checking for ancients and not MIBs
            if #MENURES = #FALSE
            {
              ignoreitem #FINDID 2 ; it's plain, forget it
              goto checkanddragagain
            }
          }
          else
          {
            set %ancientcount %ancientcount + 1
            set %totalancient %totalancient + 1
          }
        }
      }
     
      exevent drag #FINDID #FINDSTACK
      wait 10
      exevent dropc #BACKPACKID
      wait 20
      if #FINDTYPE in %tempitemid
      {
        if  #FINDTYPE = XVH  ||  #FINDTYPE = SVH
        {
          set %tmapcount %tmapcount + 1
          set %totaltmaps %totaltmaps + 1
          set %lootcount %lootcount + 1
        }
        if #FINDTYPE in HTD_UVH_RVH
        {
          set %mibcount %mibcount + 1
          set %totalmibs %totalmibs + 1
          set %lootcount %lootcount + 1
        }
        if #FINDTYPE = UDF
        {
          set %totalnets %totalnets + 1
          if #FINDCOL <> 2208
          {
            set %totalcolorednets %totalcolorednets + 1
            set %colorednetcount %colorednetcount + 1
            set %lootcount %lootcount + 1
          }
          else
          {
            set %netcount %netcount + 1
            set %lootcount %lootcount + 1
          }
        }
       
        set %lastloottime #SCNT - %loottime
        set %loottime #SCNT
        gosub CheckEndofProgram
      }
    }
  }
  ignoreitem reset 2
return

It is the model I use to add color or property to scripts! TM is my hero!

[Pearls]

I like the question I just started learning myself so don't learn from me, learn with me hehe After doing some google work and checking the documentation I would try something like this:

Code: [Select]

set %saltpeter SPT (whatever the objecttype is)
set %saltpeterColor 1150
 
finditem %saltpeter C_ , #BACKPACKID
if #FINDCNT > 0
{
  for #FINDINDEX 1 #FINDCNT
  {
    if #FINDCOL = %saltpeterColor
    {
      ; do specific something with this type
    }
    else
    {
      ; drag to container
    }
  }
}

Heh, Gimlet beats me in posting Oh yeah, i wanted to try it with #findcol as TM suggested hehe.

[Crisis]

Would just adding color and the color onto %saltpeter actually allow it to read the color?

set %saltpeter AZF
set %saltpeterColor 1150

[Pearls]

Would just adding color and the color onto %saltpeter actually allow it to read the color?

set %saltpeter AZF
set %saltpeterColor 1150

This just sets 2 seperate variables. %saltpeterColor is in no way linked to %saltpeter.
I think you need to use finditem and evaluate each stack. Evaluate either by color or by reading the property.

I'll play around with this myself tomorrow The sub Gimlet posted looks interesting.
- Check out for example the part where it's commented "MIB, but ancient?". There they read the property as a string to see if ancient is in the text. (if ancient notin #PROPERTY)

I've been playing around with "MWinc. Armor Crafter" script because i want to make a woodland armor crafting script. It helped me a lot to learn about property and working with strings. Here's the code i ended up with:

Code: [Select]

;[[str]] {"Len"} {string}
;[[str]] {"Pos"} {string} {sub string} [index]
;[[str]] {"Left"} {string} {length}
;[[str]] {"Right"} {string} {length}
;[[str]] {"Mid"} {string} {start} {length}
;[[str]] {"Lower"} {string}
;[[str]] {"Ins"} {string} {sub string} {start}
;[[str]] {"Del"} {string} {start} {length}
;[[str]] {"Count"} {string} {substring}

;Len    Stores the length of the string in the #strRes system variable.
;Pos    Stores the position of the sub string in the #strRes system variable. index tells which occurrence to return (if there's more than one).
;Left    Stores a part of the string taken from the left, in the #strRes system variable.
;Right   Stores a part of the string taken from the right, in the #strRes system variable.
;Mid    Stores a part of the string taken from the middle, in the #strRes system variable.
;Lower  Stores a lower case version of the string in the #strRes system variable.
;Ins    Inserts a string into the string and stores it in the #strRes system variable.
;Del    Deletes a part of the string and stores it in the #strRes system variable.
;Count  Returns the number of occurrences of substring in string

event Property RXAEBOD ; set this to the item id of an armor piece in your backpack
set %string #property
display %string
Str Count %string resist ; 5 (check how many times substring resist is found)
set %resistnum #strres ; total of 5 resists
for %index 1 %resistnum
{
  STR Pos %string Resist 1 ; 39 (get position of first 'resist' in string)
  set %end #strres - 3 ; 36
  Str Del %String 1 %end ; remove everything from string including position 36 ; result = l resist 2%
  set %string #strres
  str left %string 1 ; get first letter of string e.g. l (physical), e (fire), d (cold), n (poison), y (energy)
  if #strres = l
     set %resist physical
  if #strres = e
     set %resist Fire
  if #strres = d
     set %resist Cold
  if #strres = n
     set %resist Poison
  if #strres = y
     set %resist Energy
  STR Pos %string Resist 1 ; should always be 3 i guess ; e.g. l resist 2%
  set %end #strres + 6 ; removing everything from string up to the string resist value ; 9 characters ("l resist " = 9)
  Str Del %String 1 %end ; removing everything from string up to the string resist value ; l resist 2% => 2%
  set %string #strres
  Str Pos %string % ; either 2 or 3 for armor resist ; 2% or 12%
  set %delete #strres ; think this is not being used anywhere...
  set %left #strres - 1 ; get the resist value, e.g. 12% => % is position 3, 3 - 1 = 2, get first 2 characters of string = 12
  STR Left %string %left ; get the resist value
  set % . %Resist #strres ; dynamically setting resist variables %physical %cold etc
}
- Then theres the part where he checks if the net is colored or not. (if #FINDCOL <> 2208)

[Crisis]

I set up this little script to see if I could get it to distinguish between them. Unfortunately it doesn't work and I am completely stumped. I have tried all kinds of different ways to check color and move the saltpeter.

Code: [Select]

set %resourcex 475
set %resourcey 450

  ; locate/open resource secure
  str len %ResourceSecure
  if ( N/A notin %ResourceSecure ) && ( #strres > 0 )
  {
    finditem %ResourceSecure
    if #findkind <> -1
      goto _openres
  }
  _selres:
  display Ok Select your Resource Container.
  set #targcurs 1
  while #targcurs = 1
    wait 10
  set %ResourceSecure #ltargetid
  _openres:
  set #lobjectid %ResourceSecure
  event macro 17 0
  wait 10
  contpos %resourcex %resourcey
  wait 10
  gosub CheckColor

;===================================================================
  
sub CheckColor
  finditem AFZ C_ , %ResourceSecure
     wait 10
      [
     if #findcol = 1150
        set %resoucrce 1
     if #findcol = 1190
        set %resource 2
     if #findcol = 1102
        set %resource 3
     if #findcol = 1109
        set %resource 4
      ]
   gosub CheckSaltpeter
;===================================================================

sub CheckSaltpeter
  finditem %resource1 C_ , #backpackid
  if #findstack <= 20
  {
    wait 10
    gosub moveit #backpackid %ResourceSecure %resource1 200
    wait 10
    if #result = 0
    {
      display Out of saltpeter in secure, halting...
      halt
    }
  }
  pause
return

;===================================================================

sub moveit
  ; %1 destination container ID
  ; %2 source container ID, or * (any except destination), or # (ground)
  ; %3 specific item types to move, or * (all found items)
  ; %4 optional, stacksize
  set %_max 60000
  set %_total 0
  if %0 = 4
    set %_max %4
  set %_from C_ , %2
  if * in %2
    set %_from C
  if # in %2
    set %_from G_2
  finditem %3 %_from
  if #findkind = -1
    return %_total
  set %pd _NULL_
  if * in %2
    set %pd #charid
  for #findindex 1 #findcnt
  {
    if ( #findbagid <> %1 ) && ( #findbagid <> %pd )
    {
      set %_amt %_max
      if #findstack < %_max
        set %_amt #findstack
      set %_total %_total + %_amt

      exevent drag #findid %_amt
      wait 5
      if %1 = #charid
        exevent droppd
      else
        exevent dropc %1
      wait 10
    }
  }
return %_total

;===================================================================

[Crisis]

This solves my problem here, got some help on EUO. I was worried that no one would see it due to the limited activity in their script debug thread but luckily there are some that still read it. I am posting this here in case anyone else runs into the same problem and needs a fix! 

Code: [Select]

  finditem afz c_ , %ResourceSecure
{
  for #findindex 1 #findcnt
  {
    set %resource . #findcol #findid
  }
}
%resource1150 = #findid of saltpeter
%resource1190 = #findid of charcoal
%resource1102 = #findid of potash
%resource1109 = #findid of blackpowder


[Pearls]

This solves my problem here, got some help on EUO. I was worried that no one would see it due to the limited activity in their script debug thread but luckily there are some that still read it. I am posting this here in case anyone else runs into the same problem and needs a fix!  

Code: [Select]

 finditem afz c_ , %ResourceSecure
{
  for #findindex 1 #findcnt
  {
    set %resource . #findcol #findid
  }
}
%resource1150 = #findid of saltpeter
%resource1190 = #findid of charcoal
%resource1102 = #findid of potash
%resource1109 = #findid of blackpowder


The code you posted basically sets dynamic variables for you to use.
What happens if we call a variable that isn't set in EasyUO? I haven't tried hehe

I'm guessing the code i posted should work then as well?

Code: [Select]

set %saltpeter SPT (whatever the objecttype is)
set %saltpeterColor 1150
 
finditem %saltpeter C_ , #BACKPACKID
if #FINDCNT > 0
{
  for #FINDINDEX 1 #FINDCNT
  {
    if #FINDCOL = %saltpeterColor
    {
      ; do specific something with this type
    }
    else
    {
      ; drag to container
    }
  }
}


Let's analyze your code a bit (anyone can correct me if i'm wrong, i'm beginner at this )

Code: [Select]

sub CheckColor
  finditem AFZ C_ , %ResourceSecure

You mentioned that you were looking for a way to distinguish between items that share the same objecttype right?
So with this you might find saltpeter & charcoal & others right?
-> If that is the case, i think you need to iterate, loop through, the result of finditem. Charcoal, saltpeter, ... will all have a different index.
-> for #findindex 1 #findcnt

Code: [Select]

sub CheckColor
  finditem AFZ C_ , %ResourceSecure
     wait 10
      [
     if #findcol = 1150
        set %resoucrce 1
     if #findcol = 1190
        set %resource 2
     if #findcol = 1102
        set %resource 3
     if #findcol = 1109
        set %resource 4
      ]
   gosub CheckSaltpeter
;===================================================================

sub CheckSaltpeter
  finditem %resource1 C_ , #backpackid
  if #findstack <= 20
  {
    wait 10
    gosub moveit #backpackid %ResourceSecure %resource1 200
    wait 10
    if #result = 0
    {
      display Out of saltpeter in secure, halting...
      halt
    }
  }
  pause
return

- The sub CheckColor doesn't have a return at the end
- What are the square brackets? Same as {}?
- set %resoucrce 1 has a typo
- set %resource 1
=> this basically sets a local variable named 'resource' to a string 1 (or is it an integer? no idea)
but in your sub CheckSaltpeter you are using 'finditem %resource1' which you have never set, you have set %resource to the value of 1

[manwinc]

Are you trying to Just pull resources into your Bag Crisis?

Gosub Resource (Secure) (Item Type) (Color) (Minimum) (Maximum)

Just add the Sub and Put that Line into your Crafting Cycle with the appropriate variables and it will make sure that if you are below the Minimum Value that it pulls the Appropriate # to get you back up to your Maximum.

Code: [Select]

Sub Resource
; Gosub Resource (Secure) (Type) (Col) (Min) (Max)
Namespace Push
Namespace Local Mwinc_Resource
set !Cont_Id %1
set !Resource %2
set !Col %3
set !Min %4
set !Max %5
Finditem !Resource C_ , #backpackid
set !Amount 0
for #findindex 1 #findcnt
{
if #Findcol = !Col || !Col = N/A
set !Amount !Amount + #Findstack
}
if !Amount >= !Min
{
Namespace Pop
Return 0
}
set !Amount2 !Max - !Amount
if !Cont_id <> N/A
Finditem !Resource C_ , !Cont_Id
Else
Finditem !Resource C
if #findcnt > 0
{
For #findindex 1 #findcnt
{
if ( #findcol = !Col || !Col = N/A ) && #Findbagid <> #Backpackid
{
Exevent drag #Findid !Amount2
wait 15
Exevent dropc #backpackid
wait 15
set #Result !Amount2
Namespace Pop
Return #Result
}
}
}
Namespace Pop
Return Out

[Crisis]

Yes, I want it to pull from a resource container and put it in my bag. I am working on a quick and easy script to make cannon munitions. I have been looting, plundering, and pirating like a mad man and quickly run out of supplies.

[manwinc]

Just Test out that resource sub I sent you, I use it in all my crafting stuff. Pretty easy. I use wait 15 between drag and drop which can be changed. It works for me on a good connection and a slightly laggy connection.

[Crisis]

Just Test out that resource sub I sent you, I use it in all my crafting stuff. Pretty easy. I use wait 15 between drag and drop which can be changed. It works for me on a good connection and a slightly laggy connection.

I have been checking my messages but I never got anything.