Official ScriptUO EasyUO Scripts > Scripting Chat

Garbage Can Check

(1/1)

Khameleon:
has anyone Written a snippet to check if a garbage can is nearly full?

TrailMyx:
My 3.0 IDOC looter should have a couple subs that can manage the item count and weight.  I can rip those out for ya.

Khameleon:
greatly appreciated, I haven't quiet yet learned how to pull apart strings that well yet.
actually very little I have in the past and its taken hours of testing before it was almost right :P

TrailMyx:
ok, here they are. These should work in both RunUO or OSI.


--- Code: ---sub TM_GetItemCount
  namespace push
  namespace local GIC
  set !item %1
  finditem !item *
  set #RESULT -1
  if #FINDKIND <> -1
  {
    event property #FINDID
    set !string #PROPERTY
    str pos !string Contents: ; OSI
    if #STRRES <> 0
    {
      set !start #STRRES + 10
      str pos !string /
      set !len #STRRES - !start
      str mid !string !start !len
      set #RESULT #STRRES
    }
    else
    {
      str pos !string Items, ; RunUO 2.0
      if #STRRES <> 0
      {
        set !end #STRRES
        set !ptr !end - 1
        repeat
          set !ptr !ptr - 1
          str mid !string !ptr 1
        until #STRRES notin _0_1_2_3_4_5_6_7_8_9_
        set !ptr !ptr + 1
        set !len !end - !ptr - 1
        str mid !string !ptr !len
        set #RESULT #STRRES
      }
    }
  }
  namespace pop
return #RESULT

sub TM_GetItemWeight
  namespace push
  namespace local GIC
  set !item %1
  finditem !item *
  set #RESULT -1
  if #FINDKIND <> -1
  {
    event property #FINDID
    set !string #PROPERTY
    str pos !string Weight:
    if #STRRES <> 0
    {
      set !start #STRRES + 8
      str pos !string Stones$
      set !len #STRRES - !start - 1
      str mid !string !start !len
      set #RESULT #STRRES
    }
    else
    {
      str pos !string Stones$ ; RunUO 2.0
      if #STRRES <> 0
      {
        set !end #STRRES
        set !ptr !end - 1
        repeat
          set !ptr !ptr - 1
          str mid !string !ptr 1
        until #STRRES notin _0_1_2_3_4_5_6_7_8_9_
        set !ptr !ptr + 1
        set !len !end - !ptr - 1
        str mid !string !ptr !len
        set #RESULT #STRRES
      }
    }
  }
  namespace pop
return #RESULT

--- End code ---

Usage is just:


--- Code: ---gosub TM_GetItemWeight XXYYZZ
display ok The weight of the container is , #SPC , #RESULT
stop

--- End code ---

Khameleon:
awesome, just making a small update to one of your lost scripts anyways :P
so it will flow even better :)

Navigation

[0] Message Index