what script would you like to see?

[OMGBurgers]

Simple script.

2 Lightning strikes
1 Armor ignore

That's it. Make it non-pixel

I think I have a pixel one! haha.  I'll see when I can do it.  I picked back up on my pvm script, and I'm working on making it so you can customize rules based on what you're fightning...  (Ex:  Feint every 5s, AI @ max mana, etc.)



Uploaded with ImageShack.us

Pretty old screenshot though.  I added in curse weapon, a minature health bar, primary/secondary special spamming, potions (refresh, str/dex only atm), and rearranged the menu so you can hide/show all my debug crap.

[Cerveza]

Code: [Select]

set %count 0

display yesno Is Armor Ignore a Primary or Secondary?$Yes = Primary, No = Secondary
if #dispRes = Yes
  set %prisec 35
else
  set %prisec 36

repeat
  event macro 15 149 ; lightning strike
  set %timeout ( #sCnt + 10 )
  gosub TM_AdvJournalSync LightningStrike
  repeat
    {
      gosub TM_AdvJournalScan LightningStrike VALID_ADVANCE lightning_precision
      wait 5
    }
  until #RESULT = #TRUE || %timeout < #sCnt
  set %count ( %count + 1 )
  if %LS = 2
    {
      event macro %prisec 0 ; 35 pri, 36 sec
      set %timeout ( #sCnt + 10 )
      gosub TM_AdvJournalSync ArmorIgnore
      repeat
        {
          gosub TM_AdvJournalScan ArmorIgnore VALID_ADVANCE penetrates_their_armor
          wait 5
        }
      until #RESULT = #TRUE || %timeout < #sCnt
      set %count 0
    }
  wait 5
until #false

;=================================================================
; Script Name: TrailMyx's Advanced Journal Scanner
; Author: TrailMyx
; Version: 1.1
; Shard OSI / FS: OSI / FS?
; Revision Date: 10/20/2007
; Purpose:
;   Use these subs to quickly find text in your #journal entries.  These subs
; use #jindex for flawless journal scanning and is much more reliable than using
; standard indexing of #journal and #SYSMSG.
;
;   Now it is possible to manage separate journals based on unrelated text.  It's now possible
; to monitor spellcasting, bandaging, stealing, or anything else without a TM_AdvJournalSync
; potentially removing text needed for another UO funciton.
;
;   New is the ability to either gosub or call these functions without the need to change the
; header!  When calling, a limit of 10 arguments is allowed, but more can be added by editing the
; call interface section.
;
;  Examples:
;     gosub TM_AdvJournalSync speech 100 ; sync "speech" journal space, set #LPC to 100 from default of 1000
;     gosub TM_AdvJournalScan speech VALID Find_this_text and_find_this_too ; will not advance copy of #jindex
;     gosub TM_AdvJournalScan heal VALID_ADVANCE you_heal_what that_patient_is_not ; advances pointer after scan
;     gosub TM_AdvJournalScan spellcast NONE fizzle ; no spam checking and doesn't advance #jindex copy automatically
;
;  Subs included:
;     TM_AdvJournalSync - Must call this in initialzation
;     TM_AdvJournalScan - see header for details....
;
;  Release history:
;    v1.0 - Initial release.
;    v1.1 - debug code added, fixed small possibility to miss an incoming journal entry
;
;  Requirements:
;    Nothing special
;
;  Credit:
;    If you use these subs, please leave credit for me somewhere in your script header.
;=================================================================
;------------------------  Call interface  -----------------------
;=================================================================
set !TM_FunctionCalled #FALSE
if %0 = 1
  gosub %1
if %0 = 2
  gosub %1 %2
if %0 = 3
  gosub %1 %2 %3
if %0 = 4
  gosub %1 %2 %3 %4
if %0 = 5
  gosub %1 %2 %3 %4 %5
if %0 = 6
  gosub %1 %2 %3 %4 %5 %6
if %0 = 7
  gosub %1 %2 %3 %4 %5 %6 %7
if %0 = 8
  gosub %1 %2 %3 %4 %5 %6 %7 %8
if %0 = 9
  gosub %1 %2 %3 %4 %5 %6 %7 %8 %9
if %0 = 10
  gosub %1 %2 %3 %4 %5 %6 %7 %8 %9 %10
if %0 = 11
  gosub %1 %2 %3 %4 %5 %6 %7 %8 %9 %10 %11
if %0 > 11
{
  display ok Too many arguments for "call", edit file.
  stop
}

if !TM_FunctionCalled = #TRUE
  exit
if %0 = N/A
  display ok You may not run this script directly.
else
  display ok Function " , %1 , " not found.
stop
;-------------------------------------------------------------------------------
;-------------------------------------------------------------------------------
; %1 - Journal Name
; %2 - #LPC setting (optional)
; Brings !_jindex up to the most recent #journal entry
sub TM_AdvJournalSync
  namespace push
  namespace local TM_AdvJS_ , %1
  set !_jindex #jindex + 1
  if %0 > 1
    set !lpc_set %2
  namespace pop
  set !TM_FunctionCalled #TRUE
return
;-------------------------------------------------------------------------------
; %1 - Journal Name
; %2 - NONE, ADVANCE , ( _VALID ) - advances jindex pointer, anything else
; %3, %4, %5, etc strings to match
; returns #TRUE for match, #FALSE for no match
;  Will not advance !_jindex pointer to allow for scanning journal history for more than one search.
;  Also searches for : , #SPC in journal entry to be sure someone isn't spamming the text
;  About %2 arguments:
;    NONE: defaults to basic journal scan (no SPAM checking, no #jindex pointer copy advancing)
;    ADVANCE: no spam checking, advances #jindex copy
;    VALID: invokes SPAM filtering, no advance of #jindex copy
;    VALID_ADVANCE, VALIDADVANCE, ADVANCE_VALID, etc.: invokes SPAM filtering, advances of #jindex copy
sub TM_AdvJournalScan
  namespace push
  namespace local TM_AdvJS_ , %1
  set !args %2
  set !temp_lpc #LPC
  if !lpc_set = N/A
    set #LPC 1000
  else
    set #LPC !lpc_set
  set !num_args %0
  set !first_arg 3
  set !sampled_jindex #JINDEX
  if !_jindex = N/A
    set !_jindex !sampled_jindex
  if !charname = N/A
  {
    set !charname #CHARNAME
    AdvJournalScan_loop1:
      str pos !charname #SPC
      if #STRRES <> 0
      {
        set !val #STRRES - 1
        str left !charname !val
        set !left #STRRES
        set !val !val + 1
        str del !charname 1 !val
        set !charname !left , _ , #STRRES
        goto AdvJournalScan_loop1
      }
  }
  set !index !first_arg
  repeat
    set !temp_jindex !_jindex
    set !text % . !index
    while !temp_jindex <= !sampled_jindex
    {
      scanjournal !temp_jindex
      str pos #JOURNAL !charname 1
      set !namepos #STRRES
      str count #JOURNAL !charname
      set !namecnt #STRRES
      str pos #JOURNAL :_ 1
      set !smcpos #STRRES
      str pos #JOURNAL !text 1
      set !textpos #STRRES
      if !textpos < !smcpos && !smcpos <> 0 || !smcpos = 1 || :_ notin #JOURNAL || VALID notin !args
        set !pass #TRUE
      else
        set !pass #FALSE
      if ( !text in #journal && ( ( !namepos = 1 && !namecnt <= 1 ) || !pass ) )
      {
        set !temp_jindex !temp_jindex + 1
        if ADVANCE in !args
          set !_jindex !temp_jindex
        set #LPC !temp_lpc
        namespace pop
        set !TM_FunctionCalled #TRUE
        return #TRUE
      }
      set !temp_jindex !temp_jindex + 1
    }
    set !index !index + 1
  until !index - !first_arg > !num_args - !first_arg
  set %10 !sampled_jindex - !_jindex
  set %10 %1 , _ , %10 ; for debugging purposes
  set #LPC !temp_lpc
  namespace pop
  set !TM_FunctionCalled #TRUE
return #FALSE


Not tested, looks good on paper

[luv2luvlong]

If you really looking for something to do.

I would realy love to see a simple cross healing script that dosen't use the journal for checking when to heal

1 script checking 2 clients and applying aids when needed, might be a better way to explain it.

peace

[Cerveza]

That's a classic beginner script right there.

Very easy to do.

[OMGBurgers]

If you really looking for something to do.

I would realy love to see a simple cross healing script that dosen't use the journal for checking when to heal

1 script checking 2 clients and applying aids when needed, might be a better way to explain it.

peace

For reliability I would really use journal scanning.  A simple debuff can throw off a script that don't know exactly when the bandage is done, because its going off a fixed wait, and cause it to apply the next bandage before the current one is finished because your dex lowered.  Of course you could get fancy & adjust the wait based on the characters dex too  (I usually do that for a SCNT2 timeout incase something went terribly wrong!), but I'm sure it could still get messed up from being clumsy/cursed mid bandage. 

Best way to do it would be journal scanning and logging the last #jindex in a variable that starts with #charid, so swapping in no way messes up the script.

But that's just too simple of a script.  I was looking for a project to work on.

[Dixie Wrecked]

But that's just too simple of a script.  I was looking for a project to work on.

If you're looking for a larger project, here are 3 of them that i have in the works, all in the beginning stages, but with at least some code and other research done for each:

1) A BOD sorter, currently only for smith bods (tailor bods would be worth adding later, but getting it working for smith is much more desirable).  I have it set to find backpacks, bags, and pouches around my character, with one type of container full of unsorted bod books, one container type to hold the books of sorted bods (ValoriteHammer, VeriteHammer, etc, although I also plan to allow it to be expanded so that instead of all VeriteHammer BODs being in one book, all the 20ex ver plate bods are in one, all the 10 ex val plate bods are in one, and all the 15 ex val plate bods are in one, although this would lead to a LOT of storage books in the end, but a lot easier to find what is needed as well).  The third container type had one container full of empty bod books (if more aren't needed - undetermined if 2 containers full are needed), and at least 4 empty containers, to hold the bods removed from the book (up to 125 are added to each container).  It then sorts all the bods, either putting the iron smalls that give crap rewards back into their original books to be filled for recycling, or if desired, stored in books by rewards as well.

2) A new BOD Filler.  I have used snicker 7's BOD filler extensively, and there seems to be a number of places that it goes into a continuous loop, etiher discovered by myself or others.  Rather than trying to fix his code (which I haven't been able to do, although I have added checks into my multi-book bod filler script to overcome some of the issues), I felt a new script was needed, and while I would much rather have tried writing it in oEUO, I just haven't grasped enough of it yet (or much of it, even). 

3) A fishing quester.  In order to try getting fishing powerscrolls and possible the other new loot being added, as well as use up my stockpile of fish, I have started work on a fishing quester, to automatically get and fill fishing quests from the fishmongers.  I have a small area for sailing that allows me to get to any area I need, except papua, without having to sail to each destination, and by placing a second boat near the sea market, that can also be reached and have quests completed.  While still a lot of work left to complete this one as well, i would basically recall to all the fishmongers on it's subserver to get quests from them.  Then it would fill the quests, and if one of the destinations was already on the same subserver, complete the quest and get a new one from the monger who originally gave it.  Once all quests are filled and not on the same subserver you are already on, it will sail to the next subserver and continue, and then continuously do this until it runs out of fish.  The first outline calls for cancelling any quest to papua, due to the time needed to actually sail there (although i am going to test a couple more things with it), but otherwise, it can do all of the other fishmonger locations.  It would put all the loot it receiving into a container at the house with all the fish, including combining baits, and could be pretty lucrative.

As I said, I already have all 3 of these in the works, although I don't know how public they should become due to being a little too powerful (although if it was better, I would be more than happy to lead on making any or all of them a special project, especially if it would get a few other scripters out there to be able to help with some code and allow these things to really see some life - and i am sure I would learn so much more than I already know, which might even be more valuable than the finished script could ever be...I am also willing to help anyone who wishes to tackle these, especially if it was to be attempted in oEUO, as I would love to learn some more of the language, even after writing a small gift gathering script that I don't know if I fully comprehend!)...

[splatter666]

OMGBurgers where can i found that PvM script? wanted to try it out just nearly what i was searching for. Add self healing and heal partner with bandies. Than using Myst maybe with healstone and so and its the perfect PvM script :-)
With the setting of rules what should be used its fantastic.
just like:
AI from max mana to  end than wait for full mana again
alwya curse weap
allways counter attack
always
use corpse skin, like all 20 sek
bandies self


that would be great

[luv2luvlong]

That's a classic beginner script right there.

Very easy to do.

and yet I can't find a single example on the boards (here or easyuo).
and I would realy love to see a simple (or not so simple) example of multi clienting
and I thought a simple cross healer would be good.
and
and
and button stuck 

[Noobie]

That's a classic beginner script right there.

Very easy to do.

and yet I can't find a single example on the boards (here or easyuo).
and I would realy love to see a simple (or not so simple) example of multi clienting
and I thought a simple cross healer would be good.
and
and
and button stuck 

All you have to do is look at a few scripts and take examples from them. I doubt you will find a complete script like you suggested. Take a look at a few scripts that do parts of what you are wanting and go from there. Start a thread with what you have and let us help you learn from that.

[OMGBurgers]

But that's just too simple of a script.  I was looking for a project to work on.

If you're looking for a larger project, here are 3 of them that i have in the works, all in the beginning stages, but with at least some code and other research done for each:

1) A BOD sorter, currently only for smith bods (tailor bods would be worth adding later, but getting it working for smith is much more desirable).  I have it set to find backpacks, bags, and pouches around my character, with one type of container full of unsorted bod books, one container type to hold the books of sorted bods (ValoriteHammer, VeriteHammer, etc, although I also plan to allow it to be expanded so that instead of all VeriteHammer BODs being in one book, all the 20ex ver plate bods are in one, all the 10 ex val plate bods are in one, and all the 15 ex val plate bods are in one, although this would lead to a LOT of storage books in the end, but a lot easier to find what is needed as well).  The third container type had one container full of empty bod books (if more aren't needed - undetermined if 2 containers full are needed), and at least 4 empty containers, to hold the bods removed from the book (up to 125 are added to each container).  It then sorts all the bods, either putting the iron smalls that give crap rewards back into their original books to be filled for recycling, or if desired, stored in books by rewards as well.

2) A new BOD Filler.  I have used snicker 7's BOD filler extensively, and there seems to be a number of places that it goes into a continuous loop, etiher discovered by myself or others.  Rather than trying to fix his code (which I haven't been able to do, although I have added checks into my multi-book bod filler script to overcome some of the issues), I felt a new script was needed, and while I would much rather have tried writing it in oEUO, I just haven't grasped enough of it yet (or much of it, even). 

3) A fishing quester.  In order to try getting fishing powerscrolls and possible the other new loot being added, as well as use up my stockpile of fish, I have started work on a fishing quester, to automatically get and fill fishing quests from the fishmongers.  I have a small area for sailing that allows me to get to any area I need, except papua, without having to sail to each destination, and by placing a second boat near the sea market, that can also be reached and have quests completed.  While still a lot of work left to complete this one as well, i would basically recall to all the fishmongers on it's subserver to get quests from them.  Then it would fill the quests, and if one of the destinations was already on the same subserver, complete the quest and get a new one from the monger who originally gave it.  Once all quests are filled and not on the same subserver you are already on, it will sail to the next subserver and continue, and then continuously do this until it runs out of fish.  The first outline calls for cancelling any quest to papua, due to the time needed to actually sail there (although i am going to test a couple more things with it), but otherwise, it can do all of the other fishmonger locations.  It would put all the loot it receiving into a container at the house with all the fish, including combining baits, and could be pretty lucrative.

As I said, I already have all 3 of these in the works, although I don't know how public they should become due to being a little too powerful (although if it was better, I would be more than happy to lead on making any or all of them a special project, especially if it would get a few other scripters out there to be able to help with some code and allow these things to really see some life - and i am sure I would learn so much more than I already know, which might even be more valuable than the finished script could ever be...I am also willing to help anyone who wishes to tackle these, especially if it was to be attempted in oEUO, as I would love to learn some more of the language, even after writing a small gift gathering script that I don't know if I fully comprehend!)...

I'd probably get too bored with the bod sorter one.  I've written an auto smith bod filler, that would fill/turnin/drop-off rinse/repeat but I stopped working on it when my keep was full of POF's & bronze hammers.  Occasionally after 8 hours of it running I'd come home to it messed up, so it's got some issues. I'm down to about 50 or so bottles left, so I thought about working on it again, or rewriting from scratch.  I can say it is a LOT faster than the s7 one though!  I'm not sure if I'd write support for tailoring bods, as I would have no desire to do them, and the rewards are inferior/useless now imo.  I also don't have high seas, so can't do that one at all.

I'll think about the smith bod one, but it wouldn't be endless cycling full automatic, just fill an entire book. 

[luv2luvlong]

That's a classic beginner script right there.

Very easy to do.

and yet I can't find a single example on the boards (here or easyuo).
and I would realy love to see a simple (or not so simple) example of multi clienting
and I thought a simple cross healer would be good.
and
and
and button stuck 

All you have to do is look at a few scripts and take examples from them. I doubt you will find a complete script like you suggested. Take a look at a few scripts that do parts of what you are wanting and go from there. Start a thread with what you have and let us help you learn from that.

I have looked high and low and have not yet found a script that does multi clienting, nor are there any tutorials on doing it.

[OMGBurgers]

What kinda of ingo you need on multi clienting?  I don't think there's too much to it.  I use the Swap commands to swap between clients.  You can see the amount of clients available in #CLICNT, and there's another variable that shows which one is active I believe but don't know it off the top of my head.

I started to write a bunch of junk but it was a mess!  I'll whip something simple up for how I'd structure the multi client bandage healing w/o jindex scanning.

[OMGBurgers]

I guess this would be how I'd write one if I wanted something in a hurry...
I'm not sure if the % . #charid . _timeout is formated correctly, I always mess that up and would have to be able to play the script to see, but stupid easyuo is down as we all know!
%BANDAGEDELAY could be a preset number or set in the bandage sub based off the users dex  (this uses #SCNT2 so 10 = 1s)
BANDAGE would need the bandage item type obviously

I'm not sure this would work, just a rough idea how I would start

Code: [Select]

loop:
   uoxl SWAP
   if % . #CHARID . _timeout > #SCNT2 && % . #CHARID . _timeout > #SCNT2 <> N/A
      goto loop  ;if the timeout has not been met,  goto loop and check next client
                 ;otherwise the timer is active (a bandage is being applied)
   if #HITS <> #MAXHITS
      {
      gosub BANDAGESUB  ;would find bandages, apply them, and execute next line...
      set % . #CHARID . _timeout #SCNT2 + %BANDAGEDELAY  ;sets/resets when the bandage should be done
      }
goto loop

sub BANDAGESUB
   finditem BANDAGE C_ , #backpackid
   if #findkind = -1
      return ;there's no bandages...  this returns nothing and the timer still gets reset
             ;even though you did nothing.  you can return a result and do another check
             ;before setting the timer variable. maybe execute a sound to alert the user that
             ;somethings wrong without interupting the script or other clients from healing
   set #LOBJECTID #FINDID
   while #TARGCURS <> 1
      event macro 17  ;keep using #lobjectid until bandage cursor is up
   while #TARGCURS = 1
      event macro 23  ;keep targeting self until target cursor is gone
   ;bandage has been applied..  return, set timer and goto next client asap!
return


[luv2luvlong]

nice snippit
another question
 
would it be better to use one tab of easyou or 2 , or maybe 2 copys of easy running and using global variables to tell when to apply bandies.

[Cerveza]

HERE is an example of using client swapping. Note that the "trigger" is when the followers is low. Just change the trigger to hp's.

HERE is an example of using bandages, no timer or journal verification, but another swap example on conditions.

Use those to learn how to swap clients. Get a simple bandage script (EUO has one) to learn how to use bandages with journal scanning. TM's healer is a great example of that.